tv/3modules/im.nix


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72

{ config, pkgs, ... }: let
  im = config.tv.im;
  lib = import <stockholm/lib>;
in {
  options = {
    tv.im.client.enable = lib.mkEnableOption "tv.im.client" // {
      default = config.krebs.build.host.name == im.client.host.name;
    };
    tv.im.client.term = lib.mkOption {
      default = "rxvt-unicode-256color";
      type = lib.types.filename;
    };
    tv.im.client.useIPv6 = lib.mkEnableOption "tv.im.client.useIPv6" // {
      default = true;
    };
    tv.im.client.host = lib.mkOption {
      default = config.krebs.hosts.xu;
      type = lib.types.host;
    };
    tv.im.client.user = lib.mkOption {
      default = config.krebs.users.tv;
      type = lib.types.user;
    };

    tv.im.server.enable = lib.mkEnableOption "tv.im.server" // {
      default = config.krebs.build.host.name == im.server.host.name;
    };
    tv.im.server.host = lib.mkOption {
      default = config.krebs.hosts.nomic;
      type = lib.types.host;
    };
    tv.im.server.user = lib.mkOption {
      default = config.krebs.users.tv;
      type = lib.types.user;
    };
  };
  imports = [
    (lib.mkIf im.client.enable {
      users.users.${im.client.user.name}.packages = [
        (pkgs.writeDashBin "im" ''
          exec ${pkgs.openssh}/bin/ssh \
              ${lib.optionalString im.client.useIPv6 "-6"} \
              ${im.server.user.name}@${lib.head im.server.host.nets.retiolum.aliases} \
              -t \
              im
        '')
      ];
    })
    (lib.mkIf im.server.enable {
      services.bitlbee = {
        enable = true;
        plugins = [
          pkgs.bitlbee-facebook
        ];
      };
      users.users.${im.server.user.name}.packages = [
        (pkgs.writeDashBin "im" ''
          export PATH=${lib.makeSearchPath "bin" [
            pkgs.tmux
            pkgs.gnugrep
            pkgs.weechat
          ]}
          if tmux list-sessions -F\#S | grep -q '^im''$'; then
            exec tmux attach -t im
          else
            exec tmux new -s im weechat
          fi
        '')
      ];
    })
  ];
}