blob: 5250ee67aaea139a44d6cd13b73f3b6d51eb4eab (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
|
{ config, lib, pkgs, ... }:
with import <stockholm/lib>; #genid
let
cfg = config.makefu.airdcpp;
out = {
options.makefu.airdcpp = api;
config = lib.mkIf cfg.enable imp;
};
api = with types;{
enable = mkEnableOption "airdcpp";
package = mkOption {
type = package;
default = pkgs.airdcpp-webclient;
};
user = mkOption {
description = ''
user which will run udpt. if kept default a new user will be created
'';
type = str;
default = "airdcpp";
};
extraGroups = mkOption {
description = ''extra groups for the user (only for default user)'';
type = listOf str;
default = [];
example = [ "nginx" ];
};
stateDir = mkOption {
description = ''
directory for storing state (pid,config)
'';
type = str;
default = "/var/lib/airdcpp";
};
dcpp = {
Nick = mkOption {
description = ''
Nick Name for connection
'';
type = str;
default = "kevin";
};
InPort = mkOption {
description = "Input Port";
type = int;
default = 16849;
};
UDPPort = mkOption {
description = "UDP open Port";
type = int;
default = 16849;
};
TLSPort = mkOption {
description = "TLS open Port";
type = int;
default = 16869;
};
DownloadSpeed = mkOption {
description = "Total Download Speed in Mbps/s";
type = str;
default = "100";
};
UploadSpeed = mkOption {
description = "Total Upload Speed in Mbp/s";
type = str;
default = "100";
};
shares = mkOption {
default = {};
type = attrsOf (submodule ( { config, ... }: {
options = {
path = mkOption {
description = "path to the share";
type = str;
};
incoming = mkOption {
description = "incoming";
type = bool;
default = false;
};
};
}));
};
initialConfigFile = mkOption {
description = ''
path inital DCPlusPlus.xml configuration if none exists
'';
type = nullOr path;
default = null;
};
};
web = {
port = mkOption {
description = ''web-ui port
NOTE: once the initial config had been written to the state directory it will not be replaced
'';
type = int;
default = 5600;
};
initialConfigFile = mkOption {
description = ''
path inital WebServer.xml configuration if none exists
'';
type = nullOr path;
default = null;
};
# TODO: tlsPort
users = mkOption {
type = attrsOf (submodule ( { config, ... }: {
options = {
password = mkOption {
description = "password of user";
type = str;
};
permissions = mkOption {
description = "user permissions";
type = str;
default = "admin";
};
};
}));
};
};
};
imp = let
genUsers = users: concatMapStringsSep "\n" (user:
''<WebUser Username="${user.name}" Password="${user.password}" LastLogin="0" Permissions="${user.permissions}"/>'' )
(mapAttrsToList (name: val: val // { inherit name; }) users);
genShares = shares: concatMapStringsSep "\n" (share:
''<Directory Virtual="stockholm" Incoming="${
if share.incoming then "1" else "0"
}" LastRefreshTime="0">${share.path}</Directory>'' )
(mapAttrsToList (name: val: val // { inherit name; }) shares);
webConfigFile = if (cfg.web.initialConfigFile == null) then builtins.trace "warning: airdcpp passwords are stored in plain text" pkgs.writeText "initial-config" ''
<?xml version="1.0" encoding="utf-8" standalone="yes"?>
<WebServer>
<Config>
<Server Port="${toString cfg.web.port}"/>
<TLSServer Port="0" Certificate="" CertificateKey=""/>
</Config>
<WebUsers>${genUsers cfg.web.users}
</WebUsers>
</WebServer>
'' else cfg.web.initialConfigFile;
dcppConfigFile = if (cfg.dcpp.initialConfigFile == null) then pkgs.writeText "initial-config" ''
<?xml version="1.0" encoding="utf-8" standalone="yes"?>
<DCPlusPlus>
<Settings>
<Nick type="string">${cfg.dcpp.Nick}</Nick>
<ConfigVersion type="string">${cfg.package.version}</ConfigVersion>
<InPort type="int">${toString cfg.dcpp.InPort}</InPort>
<UDPPort type="int">${toString cfg.dcpp.UDPPort}</UDPPort>
<TLSPort type="int">${toString cfg.dcpp.TLSPort}</TLSPort>
<ConfigBuildNumber type="int">0</ConfigBuildNumber>
<AutoDetectIncomingConnection type="int">0</AutoDetectIncomingConnection>
<NoIpOverride type="int">1</NoIpOverride>
<WizardRunNew type="int">0</WizardRunNew>
<IPUpdate type="int">0</IPUpdate>
<AlwaysCCPM type="int">1</AlwaysCCPM>
<DownloadSpeed type="string">${cfg.dcpp.DownloadSpeed}</DownloadSpeed>
<UploadSpeed type="string">${cfg.dcpp.UploadSpeed}</UploadSpeed>
</Settings>
<Share Token="0" Name="Default">
${genShares cfg.dcpp.shares}
<NoShare/>
</Share>
<ChatFilterItems/>
</DCPlusPlus>
'' else cfg.dcpp.initialConfigFile;
in {
systemd.services.airdcpp = {
description = "airdcpp webui";
after = [ "network.target" ];
wantedBy = [ "multi-user.target" ];
restartIfChanged = true;
serviceConfig = {
Type = "simple";
ExecStartPre = pkgs.writeDash "prepare-env" ''
d=${cfg.stateDir}/WebServer.xml
test -e $d || install -m700 -o${cfg.user} ${webConfigFile} $d
d=${cfg.stateDir}/DCPlusPlus.xml
test -e $d || install -m700 -o${cfg.user} ${dcppConfigFile} $d
'';
PermissionsStartOnly = true;
ExecStart = "${cfg.package}/bin/airdcppd -c=${cfg.stateDir} -p=${cfg.stateDir}/airdcpp.pid";
PrivateTmp = true;
WorkingDirectory = cfg.stateDir;
User = "${cfg.user}";
};
};
users = lib.mkIf (cfg.user == "airdcpp") {
users.airdcpp = {
uid = genid "airdcpp";
home = cfg.stateDir;
createHome = true;
inherit (cfg) extraGroups;
};
groups.airdcpp.gid = genid "airdcpp";
};
};
in
out
|
