krebs/3modules/brockman.nix


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38

{ pkgs, config, ... }:
with import <stockholm/lib>;
let
  cfg = config.krebs.brockman;
in {
  options.krebs.brockman = {
    enable = mkEnableOption "brockman";
    config = mkOption { type = types.attrs; }; # TODO make real config here
  };

  config = mkIf cfg.enable {
    users.extraUsers.brockman = {
      home = "/var/lib/brockman";
      group = "brockman";
      createHome = true;
      isSystemUser = true;
      uid = genid_uint31 "brockman";
    };
    users.groups.brockman = {};

    systemd.services.brockman = {
      description = "RSS to IRC broadcaster";
      wantedBy = [ "multi-user.target" ];
      after = [ "network-online.target" ];
      serviceConfig = {
        Restart = "always";
        ExecStart = ''
          ${pkgs.brockman}/bin/brockman ${pkgs.writeText "brockman.json" (builtins.toJSON cfg.config)}
        '';
        User = config.users.extraUsers.brockman.name;
        PrivateTmp = true;
        RuntimeDirectory = "brockman";
        WorkingDirectory = "%t/brockman";
        RestartSec = 5;
      };
    };
  };
}