From 06cb4d25ef40773e2cc516e50a9aeec6cbe1d0a8 Mon Sep 17 00:00:00 2001
From: tv <tv@shackspace.de>
Date: Tue, 28 Jul 2015 21:38:22 +0200
Subject: */krebs -> krebs/*

---
 krebs/4lib/default.nix |  18 ++++++++
 krebs/4lib/dns.nix     |  31 ++++++++++++++
 krebs/4lib/listset.nix |  11 +++++
 krebs/4lib/tree.nix    |  13 ++++++
 krebs/4lib/types.nix   | 109 +++++++++++++++++++++++++++++++++++++++++++++++++
 5 files changed, 182 insertions(+)
 create mode 100644 krebs/4lib/default.nix
 create mode 100644 krebs/4lib/dns.nix
 create mode 100644 krebs/4lib/listset.nix
 create mode 100644 krebs/4lib/tree.nix
 create mode 100644 krebs/4lib/types.nix

(limited to 'krebs/4lib')

diff --git a/krebs/4lib/default.nix b/krebs/4lib/default.nix
new file mode 100644
index 000000000..b67585335
--- /dev/null
+++ b/krebs/4lib/default.nix
@@ -0,0 +1,18 @@
+{ lib, ... }:
+
+with builtins;
+with lib;
+
+builtins // lib // rec {
+
+  addName = name: set:
+    set // { inherit name; };
+
+  addNames = mapAttrs addName;
+
+  types = import ./types.nix { inherit lib; };
+
+  dns = import ./dns.nix { inherit lib; };
+  listset = import ./listset.nix { inherit lib; };
+  tree = import ./tree.nix { inherit lib; };
+}
diff --git a/krebs/4lib/dns.nix b/krebs/4lib/dns.nix
new file mode 100644
index 000000000..b2cf3c24c
--- /dev/null
+++ b/krebs/4lib/dns.nix
@@ -0,0 +1,31 @@
+{ lib, ... }:
+
+let
+  listset = import ./listset.nix { inherit lib; };
+in
+
+with builtins;
+with lib;
+
+rec {
+  # label = string
+
+  # TODO does it make sense to have alias = list label?
+
+  # split-by-provider :
+  #   [[label]] -> tree label provider -> listset provider alias
+  split-by-provider = as: providers:
+    foldl (m: a: listset.insert (provider-of a providers) a m) {} as;
+
+  # provider-of : alias -> tree label provider -> provider
+  # Note that we cannot use tree.get here, because path can be longer
+  # than the tree depth.
+  provider-of = a:
+    let
+      go = path: tree:
+        if typeOf tree == "string"
+          then tree
+          else go (tail path) tree.${head path};
+    in
+    go (reverseList (splitString "." a));
+}
diff --git a/krebs/4lib/listset.nix b/krebs/4lib/listset.nix
new file mode 100644
index 000000000..3aae22f20
--- /dev/null
+++ b/krebs/4lib/listset.nix
@@ -0,0 +1,11 @@
+{ lib, ... }:
+
+with lib;
+
+rec {
+  # listset k v = set k [v]
+
+  # insert : k -> v -> listset k v -> listset k v
+  insert = name: value: set:
+    set // { ${name} = set.${name} or [] ++ [value]; };
+}
diff --git a/krebs/4lib/tree.nix b/krebs/4lib/tree.nix
new file mode 100644
index 000000000..1cd83b3f6
--- /dev/null
+++ b/krebs/4lib/tree.nix
@@ -0,0 +1,13 @@
+{ lib, ... }:
+
+with lib;
+
+rec {
+  # tree k v = set k (either v (tree k v))
+
+  # get : [k] -> tree k v -> v
+  get = path: tree:
+    if length path > 0
+      then get (tail path) tree.${head path} # TODO check if elem exists
+      else tree;
+}
diff --git a/krebs/4lib/types.nix b/krebs/4lib/types.nix
new file mode 100644
index 000000000..92410dd58
--- /dev/null
+++ b/krebs/4lib/types.nix
@@ -0,0 +1,109 @@
+{ lib, ... }:
+
+with lib;
+with types;
+
+types // rec {
+
+  host = submodule {
+    options = {
+      name = mkOption {
+        type = label;
+      };
+      dc = mkOption {
+        type = label;
+      };
+      cores = mkOption {
+        type = positive;
+      };
+      nets = mkOption {
+        type = attrsOf net;
+        apply = x: assert hasAttr "retiolum" x; x;
+      };
+      secure = mkOption {
+        type = bool;
+        default = false;
+        description = ''
+          If true, then the host is capable of keeping secret information.
+
+          TODO define minimum requirements for secure hosts
+        '';
+      };
+    };
+  };
+
+  net = submodule ({ config, ... }: {
+    options = {
+      via = mkOption {
+        type = nullOr net;
+        default = null;
+      };
+      addrs = mkOption {
+        type = listOf addr;
+        apply = _: config.addrs4 ++ config.addrs6;
+      };
+      addrs4 = mkOption {
+        type = listOf addr4;
+        default = [];
+      };
+      addrs6 = mkOption {
+        type = listOf addr6;
+        default = [];
+      };
+      aliases = mkOption {
+        # TODO nonEmptyListOf hostname
+        type = listOf hostname;
+      };
+      tinc = mkOption {
+        type = let net-config = config; in nullOr (submodule ({ config, ... }: {
+          options = {
+            config = mkOption {
+              type = str;
+              apply = _: ''
+                ${optionalString (net-config.via != null)
+                  (concatMapStringsSep "\n" (a: "Address = ${a}") net-config.via.addrs)}
+                ${concatMapStringsSep "\n" (a: "Subnet = ${a}") net-config.addrs}
+                ${config.pubkey}
+              '';
+            };
+            pubkey = mkOption {
+              type = str;
+            };
+          };
+        }));
+        default = null;
+      };
+    };
+  });
+
+  positive = mkOptionType {
+    name = "positive integer";
+    check = x: isInt x && x > 0;
+    merge = mergeOneOption;
+  };
+
+  user = submodule {
+    options = {
+      mail = mkOption {
+        type = str; # TODO retiolum mail address
+      };
+      name = mkOption {
+        type = str; # TODO
+      };
+      pubkey = mkOption {
+        type = str;
+      };
+      pubkeys = mkOption {
+        type = attrsOf str;
+        default = {};
+      };
+    };
+  };
+
+  # TODO
+  addr = str;
+  addr4 = str;
+  addr6 = str;
+  hostname = str;
+  label = str;
+}
-- 
cgit v1.2.3