From cbe70e8c394b372cab35a0520f2fb3dcc83ebd2f Mon Sep 17 00:00:00 2001
From: lassulus <lass@aidsballs.de>
Date: Tue, 15 Mar 2016 14:37:46 +0100
Subject: l 3 newsbot-js -> k 3 newsbot-js

---
 krebs/3modules/default.nix    |  1 +
 krebs/3modules/newsbot-js.nix | 89 +++++++++++++++++++++++++++++++++++++++++++
 2 files changed, 90 insertions(+)
 create mode 100644 krebs/3modules/newsbot-js.nix

(limited to 'krebs/3modules')

diff --git a/krebs/3modules/default.nix b/krebs/3modules/default.nix
index bdd9049cb..af5076e0f 100644
--- a/krebs/3modules/default.nix
+++ b/krebs/3modules/default.nix
@@ -21,6 +21,7 @@ let
       ./go.nix
       ./iptables.nix
       ./lib.nix
+      ./newsbot-js.nix
       ./nginx.nix
       ./nixpkgs.nix
       ./os-release.nix
diff --git a/krebs/3modules/newsbot-js.nix b/krebs/3modules/newsbot-js.nix
new file mode 100644
index 000000000..b58c555e7
--- /dev/null
+++ b/krebs/3modules/newsbot-js.nix
@@ -0,0 +1,89 @@
+{ config, lib, pkgs, ... }:
+
+with builtins;
+with lib;
+
+let
+  inherit (config.krebs.lib) genid;
+
+  cfg = config.krebs.newsbot-js;
+
+  out = {
+    options.krebs.newsbot-js = api;
+    config = mkIf cfg.enable imp;
+  };
+
+  api = {
+    enable = mkEnableOption "Enable krebs newsbot";
+    ircServer = mkOption {
+      type = types.str;
+      default = "echelon.retiolum";
+      description = "to which server the bot should connect";
+    };
+    channel = mkOption {
+      type = types.str;
+      default = "#news";
+      description = "post the news in this channel";
+    };
+    masterNick = mkOption {
+      type = types.str;
+      default = "knews";
+      description = "nickname of the master bot";
+    };
+    feeds = mkOption {
+      type = types.path;
+      description = ''
+        file with feeds to post
+        format:
+        $nick|$feedURI
+      '';
+    };
+    urlShortenerHost = mkOption {
+      type = types.str;
+      default = "echelon";
+      description = "what server to use for url shortening, host";
+    };
+    urlShortenerPort = mkOption {
+      type = types.str;
+      default = "80";
+      description = "what server to use for url shortening, port";
+    };
+  };
+
+  imp = {
+    users.extraUsers.newsbot-js = {
+      name = "newsbot-js";
+      uid = genid "newsbot-js";
+      description = "newsbot-js user";
+      home = "/var/empty";
+    };
+
+    systemd.services.newsbot-js = {
+      description = "krebs newsbot";
+      after = [ "network.target" ];
+      wantedBy = [ "multi-user.target" ];
+
+      path = with pkgs; [
+        newsbot-js
+      ];
+
+      environment = {
+        irc_server = cfg.ircServer;
+        master_nick = cfg.masterNick;
+        news_channel = cfg.channel;
+        feeds_file = cfg.feeds;
+        url_shortener_host = cfg.urlShortenerHost;
+        url_shortener_port = cfg.urlShortenerPort;
+      };
+
+      restartIfChanged = true;
+
+      serviceConfig = {
+        User = "newsbot-js";
+        Restart = "always";
+        ExecStart = "${pkgs.newsbot-js}/bin/newsbot";
+      };
+    };
+  };
+
+in out
-- 
cgit v1.2.3