Merge remote-tracking branch 'lass/master'

5 files changed, 250 insertions, 0 deletions

diff --git a/lass/1systems/aergia/config.nix b/lass/1systems/aergia/config.nix
new file mode 100644
index 000000000..ed5bbcf12
--- /dev/null
+++ b/lass/1systems/aergia/config.nix
@@ -0,0 +1,76 @@
+{ config, lib, pkgs, ... }:
+
+{
+  imports = [
+    <stockholm/lass>
+
+    <stockholm/lass/2configs/retiolum.nix>
+    <stockholm/lass/2configs/exim-retiolum.nix>
+    <stockholm/lass/2configs/baseX.nix>
+    <stockholm/lass/2configs/pipewire.nix>
+    <stockholm/lass/2configs/browsers.nix>
+    <stockholm/lass/2configs/programs.nix>
+    <stockholm/lass/2configs/network-manager.nix>
+    <stockholm/lass/2configs/syncthing.nix>
+    <stockholm/lass/2configs/sync/sync.nix>
+    <stockholm/lass/2configs/games.nix>
+    <stockholm/lass/2configs/steam.nix>
+    <stockholm/lass/2configs/wine.nix>
+    <stockholm/lass/2configs/fetchWallpaper.nix>
+    <stockholm/lass/2configs/yellow-mounts/samba.nix>
+    <stockholm/lass/2configs/pass.nix>
+    <stockholm/lass/2configs/mail.nix>
+    <stockholm/lass/2configs/bitcoin.nix>
+    # <stockholm/lass/2configs/xonsh.nix>
+    <stockholm/lass/2configs/review.nix>
+    <stockholm/lass/2configs/dunst.nix>
+    <stockholm/lass/2configs/print.nix>
+    <stockholm/lass/2configs/br.nix>
+  ];
+
+  system.stateVersion = "22.11";
+
+  krebs.build.host = config.krebs.hosts.aergia;
+
+  environment.systemPackages = with pkgs; [
+    brain
+    bank
+    l-gen-secrets
+    generate-secrets
+  ];
+
+  programs.adb.enable = true;
+
+  hardware.bluetooth = {
+    enable = true;
+    powerOnBoot = true;
+  };
+  hardware.pulseaudio.package = pkgs.pulseaudioFull;
+
+  lass.browser.config = {
+    fy = { browser = "chromium";  groups = [ "audio" "video" ]; hidden = true; };
+    qt = { browser = "qutebrowser";  groups = [ "audio" "video" ]; hidden = true; };
+  };
+
+  nix.trustedUsers = [ "root" "lass" ];
+
+  # nix.extraOptions = ''
+  #   extra-experimental-features = nix-command flakes
+  # '';
+
+  services.tor = {
+    enable = true;
+    client.enable = true;
+  };
+
+  documentation.nixos.enable = true;
+  boot.binfmt.emulatedSystems = [
+    "aarch64-linux"
+  ];
+
+  boot.cleanTmpDir = true;
+
+  # vbox
+  virtualisation.virtualbox.host.enable = true;
+  users.users.mainUser.extraGroups = [ "vboxusers" ];
+}
diff --git a/lass/1systems/aergia/disk.nix b/lass/1systems/aergia/disk.nix
new file mode 100644
index 000000000..0ae0892ee
--- /dev/null
+++ b/lass/1systems/aergia/disk.nix
@@ -0,0 +1,64 @@
+{ lib, ... }:
+{
+  disk = {
+    main = {
+      type = "disk";
+      device = "/dev/nvme0n1";
+      content = {
+        type = "table";
+        format = "gpt";
+        partitions = [
+          {
+            name = "boot";
+            type = "partition";
+            start = "0";
+            end = "1M";
+            part-type = "primary";
+            flags = ["bios_grub"];
+          }
+          {
+            type = "partition";
+            name = "ESP";
+            start = "1MiB";
+            end = "1GiB";
+            fs-type = "fat32";
+            bootable = true;
+            content = {
+              type = "filesystem";
+              format = "vfat";
+              mountpoint = "/boot";
+            };
+          }
+          {
+            name = "root";
+            type = "partition";
+            start = "1GiB";
+            end = "100%";
+            content = {
+              type = "luks";
+              name = "aergia1";
+              content = {
+                type = "btrfs";
+                extraArgs = "-f"; # Override existing partition
+                subvolumes = {
+                  # Subvolume name is different from mountpoint
+                  "/rootfs" = {
+                    mountpoint = "/";
+                  };
+                  # Mountpoints inferred from subvolume name
+                  "/home" = {
+                    mountOptions = [];
+                  };
+                  "/nix" = {
+                    mountOptions = [];
+                  };
+                };
+              };
+            };
+          }
+        ];
+      };
+    };
+  };
+}
+
diff --git a/lass/1systems/aergia/install.sh b/lass/1systems/aergia/install.sh
new file mode 100644
index 000000000..0e4f0ab4c
--- /dev/null
+++ b/lass/1systems/aergia/install.sh
@@ -0,0 +1,3 @@
+#!/bin/sh
+
+target=$1
diff --git a/lass/1systems/aergia/physical.nix b/lass/1systems/aergia/physical.nix
new file mode 100644
index 000000000..de5f7540e
--- /dev/null
+++ b/lass/1systems/aergia/physical.nix
@@ -0,0 +1,86 @@
+{ config, lib, pkgs, modulesPath, ... }:
+{
+  imports = [
+    ./config.nix
+    (modulesPath + "/installer/scan/not-detected.nix")
+  ];
+  disko.devices = import ./disk.nix;
+
+  networking.hostId = "deadbeef";
+  # boot.loader.efi.canTouchEfiVariables = true;
+  boot.loader.grub = {
+    enable = true;
+    device = "/dev/nvme0n1";
+    efiSupport = true;
+    efiInstallAsRemovable = true;
+  };
+
+  boot.kernelPackages = pkgs.linuxPackages_latest;
+
+  boot.kernelParams = [
+    # Enable energy savings during sleep
+    "mem_sleep_default=deep"
+    "initcall_blacklist=acpi_cpufreq_init"
+
+    # for ryzenadj -i
+    "iomem=relaxed"
+  ];
+
+  # Enables the amd cpu scaling https://www.kernel.org/doc/html/latest/admin-guide/pm/amd-pstate.html
+  # On recent AMD CPUs this can be more energy efficient.
+  boot.kernelModules = [ "amd-pstate" "kvm-amd" ];
+
+  # hardware.cpu.amd.updateMicrocode = true;
+
+  services.xserver.videoDrivers = [
+    "amdgpu"
+  ];
+
+  boot.initrd.availableKernelModules = [ "nvme" "xhci_pci" "usbhid" "usb_storage" "sd_mod" ];
+
+  environment.systemPackages = [
+    pkgs.vulkan-tools
+    pkgs.ryzenadj
+    (pkgs.writers.writeDashBin "set_tdp" ''
+      set -efux
+      watt=$1
+      value=$(( $watt * 1000 ))
+      ${pkgs.ryzenadj}/bin/ryzenadj --stapm-limit="$value" --fast-limit="$value" --slow-limit="$value"
+    '')
+  ];
+
+  # textsize
+  services.xserver.dpi = 200;
+  hardware.video.hidpi.enable = lib.mkDefault true;
+
+  # corectrl
+  programs.corectrl.enable = true;
+  users.users.mainUser.extraGroups = [ "corectrl" ];
+
+  # use newer ryzenadj
+  nixpkgs.config.packageOverrides = super: {
+    ryzenadj = super.ryzenadj.overrideAttrs (old: {
+      version = "unstable-2023-01-15";
+      src = pkgs.fetchFromGitHub {
+        owner = "FlyGoat";
+        repo = "RyzenAdj";
+        rev = "1052fb52b2c0e23ac4cd868c4e74d4a9510be57c"; # unstable on 2023-01-15
+        sha256 = "sha256-/IxkbQ1XrBrBVrsR4EdV6cbrFr1m+lGwz+rYBqxYG1k=";
+      };
+    });
+  };
+
+  # keyboard quirks
+  services.xserver.displayManager.sessionCommands = ''
+    xmodmap -e 'keycode 96 = F12 Insert F12 F12' # rebind shift + F12 to shift + insert
+  '';
+  services.udev.extraHwdb = /* sh */ ''
+    # disable back buttons
+    evdev:input:b0003v2F24p0135* # /dev/input/event2
+      KEYBOARD_KEY_70026=reserved
+      KEYBOARD_KEY_70027=reserved
+  '';
+
+  # ignore power key
+  services.logind.extraConfig = "HandlePowerKey=ignore";
+}
diff --git a/lass/1systems/aergia/source.nix b/lass/1systems/aergia/source.nix
new file mode 100644
index 000000000..abbf26c75
--- /dev/null
+++ b/lass/1systems/aergia/source.nix
@@ -0,0 +1,21 @@
+{ lib, pkgs, test, ... }: let
+  npkgs = lib.importJSON ../../../krebs/nixpkgs-unstable.json;
+in {
+  nixpkgs = (if test then lib.mkForce ({ derivation = let
+    rev = npkgs.rev;
+    sha256 = npkgs.sha256;
+  in ''
+    with import (builtins.fetchTarball {
+      url = "https://github.com/nixos/nixpkgs/archive/${rev}.tar.gz";
+      sha256 = "${sha256}";
+    }) {};
+    pkgs.fetchFromGitHub {
+      owner = "nixos";
+      repo = "nixpkgs";
+      rev = "${rev}";
+      sha256 = "${sha256}";
+    }
+  ''; }) else {
+    git.ref = lib.mkForce npkgs.rev;
+  });
+}