add minimal working kops for stockholm

3 files changed, 100 insertions, 7 deletions

diff --git a/krebs/kops.nix b/krebs/kops.nix
new file mode 100644
index 000000000..9774b5cab
--- /dev/null
+++ b/krebs/kops.nix
@@ -0,0 +1,64 @@
+{ name }: rec {
+
+  kops = (import <nixpkgs> {}).fetchgit {
+    url = https://cgit.krebsco.de/kops/;
+    rev = "e89cf20d4310070a877c2e24a287659546b561c9";
+    sha256 = "0wg8d80sxa46z4i7ir79sci2hwmv3qskzqdg0si64p6vazy8vckb";
+  };
+
+  lib = import "${kops}/lib";
+
+  # TODO document why pkgs should be used like this
+  pkgs = import "${kops}/pkgs" {};
+
+  krebs-source = {
+    nixpkgs.git = {
+      ref = "09bca91e3b5a18d7f37f7632175ac71f2bf369ff";
+      url = https://github.com/NixOS/nixpkgs;
+    };
+    stockholm.file = toString ~/stockholm;
+    stockholm-version.pipe = toString (pkgs.writeDash "${name}-version" ''
+      set -efu
+      cd $HOME/stockholm
+      V=$(${pkgs.coreutils}/bin/date +%y.%m)
+      if test -d .git; then
+        V=$V.git.$(${pkgs.git}/bin/git describe --always --dirty)
+        case $V in (*-dirty)
+          V=$V@''${HOSTNAME-$(${pkgs.nettools}/bin/hostname)}
+        esac
+      fi
+      printf %s "$V"
+    '');
+  };
+
+  source ={ test }: lib.evalSource [
+    krebs-source
+    {
+      nixos-config.symlink = "stockholm/krebs/1systems/${name}/config.nix";
+      secrets =
+        if test
+          then {
+            file = toString <stockholm/krebs/6tests/data/secrets>;
+          }
+          else {
+            pass = {
+              dir = "${lib.getEnv "HOME"}/brain";
+              name = "krebs-secrets/${name}";
+            };
+          }
+        ;
+    }
+  ];
+
+  # usage: $(nix-build --no-out-link --argstr name HOSTNAME -A deploy)
+  deploy = pkgs.kops.writeDeploy "${name}-deploy" {
+    source = source { test = false; };
+    target = "root@${name}/var/src";
+  };
+
+  # usage: $(nix-build --no-out-link --argstr name HOSTNAME -A test)
+  test = pkgs.kops.writeTest "${name}-test" {
+    source = source { test = true; };
+    target = "${lib.getEnv "HOME"}/tmp/${name}-kops-test-src";
+  };
+}
diff --git a/lass/1systems/mors/config.nix b/lass/1systems/mors/config.nix
index 8e805baf0..cd259d0fe 100644
--- a/lass/1systems/mors/config.nix
+++ b/lass/1systems/mors/config.nix
@@ -168,14 +168,8 @@ with import <stockholm/lib>;
   environment.shellAliases = {
     deploy = pkgs.writeDash "deploy" ''
       set -eu
-      export PATH=${makeBinPath [
-        pkgs.bash
-        pkgs.coreutils
-        pkgs.nixUnstable
-      ]}
-      cd ~/stockholm
       export SYSTEM="$1"
-      exec nix-shell -I stockholm="$PWD" --run 'deploy --system="$SYSTEM"'
+      $(nix-build $HOME/stockholm/lass/kops.nix --no-out-link --argstr name "$SYSTEM" -A deploy)
     '';
   };
 
diff --git a/lass/kops.nix b/lass/kops.nix
new file mode 100644
index 000000000..9d0ab911a
--- /dev/null
+++ b/lass/kops.nix
@@ -0,0 +1,35 @@
+{ name }: let
+  inherit (import ../krebs/kops.nix { inherit name; })
+    krebs-source
+    lib
+    pkgs
+  ;
+
+  source = { test }: lib.evalSource [
+    krebs-source
+    {
+      nixos-config.symlink = "stockholm/lass/1systems/${name}/config.nix";
+      secrets = if test then {
+        file = "/home/lass/stockholm/lass/2configs/tests/dummy-secrets";
+      } else {
+        pass = {
+          dir = "${lib.getEnv "HOME"}/.password-store";
+          name = "hosts/${name}";
+        };
+      };
+    }
+  ];
+
+in {
+  # usage: $(nix-build --no-out-link --argstr name HOSTNAME -A deploy)
+  deploy = pkgs.kops.writeDeploy "${name}-deploy" {
+    source = source { test = false; };
+    target = "root@${name}/var/src";
+  };
+
+  # usage: $(nix-build --no-out-link --argstr name HOSTNAME -A test)
+  test = pkgs.kops.writeTest "${name}-test" {
+    source = source { test = true; };
+    target = "${lib.getEnv "HOME"}/tmp/${name}-kops-test-src";
+  };
+}