From 1d687bb2a8e3ee0d129b01a645f998b3cdafd82d Mon Sep 17 00:00:00 2001
From: lassulus <lassulus@lassul.us>
Date: Sun, 3 Dec 2017 23:00:24 +0100
Subject: l: add xserver module

---
 lass/3modules/default.nix              |  1 +
 lass/3modules/xserver/default.nix      | 96 ++++++++++++++++++++++++++++++++++
 lass/3modules/xserver/xserver.conf.nix | 40 ++++++++++++++
 3 files changed, 137 insertions(+)
 create mode 100644 lass/3modules/xserver/default.nix
 create mode 100644 lass/3modules/xserver/xserver.conf.nix

(limited to 'lass/3modules')

diff --git a/lass/3modules/default.nix b/lass/3modules/default.nix
index e14e39bc..81b52c30 100644
--- a/lass/3modules/default.nix
+++ b/lass/3modules/default.nix
@@ -11,6 +11,7 @@ _:
     ./screenlock.nix
     ./umts.nix
     ./usershadow.nix
+    ./xserver
     ./xresources.nix
   ];
 }
diff --git a/lass/3modules/xserver/default.nix b/lass/3modules/xserver/default.nix
new file mode 100644
index 00000000..c0cb37d6
--- /dev/null
+++ b/lass/3modules/xserver/default.nix
@@ -0,0 +1,96 @@
+{ config, pkgs, ... }@args:
+with import <stockholm/lib>;
+let
+
+  out = {
+    options.lass.xserver = api;
+    config = mkIf cfg.enable imp;
+  };
+
+  user = config.krebs.build.user;
+
+  cfg = config.lass.xserver;
+  api = {
+    enable = mkEnableOption "lass xserver";
+  };
+  imp = {
+
+    services.xserver = {
+      # Don't install feh into systemPackages
+      # refs <nixpkgs/nixos/modules/services/x11/desktop-managers>
+      desktopManager.session = mkForce [];
+
+      enable = true;
+      display = 11;
+      tty = 11;
+    };
+
+    systemd.services.display-manager.enable = false;
+
+    systemd.services.xmonad = {
+      wantedBy = [ "multi-user.target" ];
+      requires = [ "xserver.service" ];
+      environment = {
+        DISPLAY = ":${toString config.services.xserver.display}";
+
+        XMONAD_STARTUP_HOOK = pkgs.writeDash "xmonad-startup-hook" ''
+          ${pkgs.xorg.xhost}/bin/xhost +LOCAL: &
+          ${config.services.xserver.displayManager.sessionCommands}
+          wait
+        '';
+
+        XMONAD_DATA_DIR = "/tmp";
+      };
+      serviceConfig = {
+        SyslogIdentifier = "xmonad";
+        ExecStart = "${pkgs.xmonad-lass}/bin/xmonad";
+        ExecStop = "${pkgs.xmonad-lass}/bin/xmonad --shutdown";
+        User = user.name;
+        WorkingDirectory = user.home;
+      };
+    };
+
+    systemd.services.xserver = {
+      after = [
+        "systemd-udev-settle.service"
+        "local-fs.target"
+        "acpid.service"
+      ];
+      reloadIfChanged = true;
+      environment = {
+        XKB_BINDIR = "${pkgs.xorg.xkbcomp}/bin"; # Needed for the Xkb extension.
+        XORG_DRI_DRIVER_PATH = "/run/opengl-driver/lib/dri"; # !!! Depends on the driver selected at runtime.
+        LD_LIBRARY_PATH = concatStringsSep ":" (
+          [ "${pkgs.xorg.libX11}/lib" "${pkgs.xorg.libXext}/lib" ]
+          ++ concatLists (catAttrs "libPath" config.services.xserver.drivers));
+      };
+      serviceConfig = {
+        SyslogIdentifier = "xserver";
+        ExecReload = "${pkgs.coreutils}/bin/echo NOP";
+        ExecStart = toString [
+          "${pkgs.xorg.xorgserver}/bin/X"
+          ":${toString config.services.xserver.display}"
+          "vt${toString config.services.xserver.tty}"
+          "-config ${import ./xserver.conf.nix args}"
+          "-logfile /dev/null -logverbose 0 -verbose 3"
+          "-nolisten tcp"
+          "-xkbdir ${pkgs.xkeyboard_config}/etc/X11/xkb"
+        ];
+      };
+    };
+    systemd.services.urxvtd = {
+      wantedBy = [ "multi-user.target" ];
+      reloadIfChanged = true;
+      serviceConfig = {
+        SyslogIdentifier = "urxvtd";
+        ExecReload = "${pkgs.coreutils}/bin/echo NOP";
+        ExecStart = "${pkgs.rxvt_unicode_with-plugins}/bin/urxvtd";
+        Restart = "always";
+        RestartSec = "2s";
+        StartLimitBurst = 0;
+        User = user.name;
+      };
+    };
+  };
+
+in out
diff --git a/lass/3modules/xserver/xserver.conf.nix b/lass/3modules/xserver/xserver.conf.nix
new file mode 100644
index 00000000..6f34e015
--- /dev/null
+++ b/lass/3modules/xserver/xserver.conf.nix
@@ -0,0 +1,40 @@
+{ config, lib, pkgs, ... }:
+
+with import <stockholm/lib>;
+
+let
+  cfg = config.services.xserver;
+in
+
+pkgs.stdenv.mkDerivation {
+  name = "xserver.conf";
+
+  xfs = optionalString (cfg.useXFS != false)
+    ''FontPath "${toString cfg.useXFS}"'';
+
+  inherit (cfg) config;
+
+  buildCommand =
+    ''
+      echo 'Section "Files"' >> $out
+      echo $xfs >> $out
+
+      for i in ${toString config.fonts.fonts}; do
+        if test "''${i:0:''${#NIX_STORE}}" == "$NIX_STORE"; then
+          for j in $(find $i -name fonts.dir); do
+            echo "  FontPath \"$(dirname $j)\"" >> $out
+          done
+        fi
+      done
+
+      for i in $(find ${toString cfg.modules} -type d); do
+        if test $(echo $i/*.so* | wc -w) -ne 0; then
+          echo "  ModulePath \"$i\"" >> $out
+        fi
+      done
+
+      echo 'EndSection' >> $out
+
+      echo "$config" >> $out
+    '';
+}
-- 
cgit v1.2.3