From d2c388ce3928764a78e4158162cb64ce3b5e43ce Mon Sep 17 00:00:00 2001
From: tv <tv@krebsco.de>
Date: Thu, 21 Sep 2017 20:59:38 +0200
Subject: iana-etc module: init

---
 krebs/3modules/iana-etc.nix | 55 +++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 55 insertions(+)
 create mode 100644 krebs/3modules/iana-etc.nix

(limited to 'krebs/3modules/iana-etc.nix')

diff --git a/krebs/3modules/iana-etc.nix b/krebs/3modules/iana-etc.nix
new file mode 100644
index 00000000..f6d47f27
--- /dev/null
+++ b/krebs/3modules/iana-etc.nix
@@ -0,0 +1,55 @@
+with import <stockholm/lib>;
+{ config, pkgs, ... }: {
+
+  options.krebs.iana-etc.services = mkOption {
+    default = {};
+    type = types.attrsOf (types.submodule ({ config, ... }: {
+      options = {
+        port = mkOption {
+          default = config._module.args.name;
+          type = types.addCheck types.str (test "[1-9][0-9]*");
+        };
+      } // genAttrs ["tcp" "udp"] (protocol: mkOption {
+        default = null;
+        type = types.nullOr (types.submodule {
+          options = {
+            name = mkOption {
+              type = types.str;
+            };
+          };
+        });
+      });
+    }));
+  };
+
+  config.environment.etc = mkIf (config.krebs.iana-etc.services != {})  {
+    services.source = mkForce (pkgs.runCommand "krebs-iana-etc" {} ''
+      exec < ${pkgs.iana_etc}/etc/services
+      exec > $out
+      awk -F '[ /]+' '
+        BEGIN {
+          port=0
+        }
+        ${concatMapStringsSep "\n" (entry: ''
+          $2 == ${entry.port} {
+            port=$2
+            next
+          }
+          port == ${entry.port} {
+            ${concatMapStringsSep "\n"
+              (proto: let
+                s = "${entry.${proto}.name} ${entry.port}/${proto}";
+              in
+                "print ${toJSON s}")
+              (filter (proto: entry.${proto} != null) ["tcp" "udp"])}
+            port=0
+          }
+        '') (attrValues config.krebs.iana-etc.services)}
+        {
+          print $0
+        }
+      '
+    '');
+  };
+
+}
-- 
cgit v1.2.3