From 100b6fc2438db6ca2c7abe0ad525be3b1dd64895 Mon Sep 17 00:00:00 2001
From: lassulus <lassulus@lassul.us>
Date: Sun, 30 Jan 2022 10:47:23 +0100
Subject: move acl module to krebs

---
 krebs/3modules/acl.nix | 55 ++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 55 insertions(+)
 create mode 100644 krebs/3modules/acl.nix

(limited to 'krebs/3modules/acl.nix')

diff --git a/krebs/3modules/acl.nix b/krebs/3modules/acl.nix
new file mode 100644
index 00000000..9cdbb6cf
--- /dev/null
+++ b/krebs/3modules/acl.nix
@@ -0,0 +1,55 @@
+{ config, lib, pkgs, ... }: let
+  parents = dir:
+    if dir == "/" then
+      [ dir ]
+    else
+      [ dir ] ++ parents (builtins.dirOf dir)
+    ;
+in {
+  options.krebs.acl = lib.mkOption {
+    type = lib.types.attrsOf (lib.types.attrsOf (lib.types.submodule ({ config, ... }: {
+      options = {
+        rule = lib.mkOption {
+          type = lib.types.str;
+          default = config._module.args.name;
+        };
+        default = lib.mkOption {
+          type = lib.types.bool;
+          default = !config.parents;
+        };
+        recursive = lib.mkOption {
+          type = lib.types.bool;
+          default = !config.parents;
+        };
+        parents = lib.mkOption {
+          type = lib.types.bool;
+          default = false;
+          description = ''
+            apply ACL to every parent folder
+          '';
+        };
+      };
+    })));
+    default = {};
+  };
+  config = {
+    systemd.services = lib.mapAttrs' (path: rules: lib.nameValuePair "acl-${lib.replaceChars ["/"] ["_"] path}" {
+      wantedBy = [ "multi-user.target" ];
+      path = [
+        pkgs.acl
+        pkgs.coreutils
+      ];
+      serviceConfig = {
+        ExecStart = pkgs.writers.writeDash "acl" (lib.concatStrings (
+          lib.mapAttrsToList (_: rule: ''
+            setfacl -${lib.optionalString rule.recursive "R"}m ${rule.rule} ${path}
+            ${lib.optionalString rule.default "setfacl -${lib.optionalString rule.recursive "R"}dm ${rule.rule} ${path}"}
+            ${lib.optionalString rule.parents (lib.concatMapStringsSep "\n" (folder: "setfacl -m ${rule.rule} ${folder}") (parents path))}
+          '') rules
+        ));
+        RemainAfterExit = true;
+        Type = "simple";
+      };
+    }) config.krebs.acl;
+  };
+}
-- 
cgit v1.2.3